架构师

您现在的位置是:首页 > 技术博客 > 爱运维

爱运维

windows批处理命令:自动安装并配置绿色版mysql的bat脚本

架构师小跟班 2020-05-12 爱运维
脚本功能:1)安装mysql(绿色免安装版mysql-5.7.20)2)配置mysql环境变量3)生成my.ini配置文件4)添加mysql到系统服务(services.msc)5)配置初始密码脚本内容:@echo offtitle 安装MYSQLecho

脚本功能:

1)安装mysql(绿色免安装版mysql-5.7.20)

2)配置mysql环境变量

3)生成my.ini配置文件

4)添加mysql到系统服务(services.msc)

5)配置初始密码

脚本内容:

@echo off

title 安装MYSQL

echo.

echo ****************************************

echo.

echo 开始安装MYSQL,请不要关闭窗口

echo.

echo 请以管理员身份运行

echo.

echo ****************************************

pause

echo.

echo 设置安装路径

echo.

set cds=%~dp0

set mysql_path=%cds%installs\mysql

echo.

echo 安装路径:%mysql_path%

echo.

echo.

echo 配置环境变量

echo.

setx PATH "%mysql_path%\bin;%path%"

IF ERRORLEVEL 1 (

echo.

echo 配置环境变量失败,即将退出

echo.

goto END

)

echo.

echo 打印环境变量

echo.

echo ****************************************

set str=%path%

set remain=%str%

:loop

for /f "tokens=1* delims=;" %%a in ("%remain%") do (

echo %%a

set remain=%%b

)

if defined remain goto :loop

echo ****************************************

echo.

echo 删除原配置文件

echo.

del %mysql_path%\my.ini

echo.

echo 写入配置

echo.

echo [mysql]>>%mysql_path%\my.ini

echo default-character-set=utf8>>%mysql_path%\my.ini

echo [mysqld]>>%mysql_path%\my.ini

echo basedir=%mysql_path%>>%mysql_path%\my.ini

echo datadir=%mysql_path%\data>>%mysql_path%\my.ini

echo port=3306>>%mysql_path%\my.ini

echo max_connections=200>>%mysql_path%\my.ini

echo character-set-server=utf8>>%mysql_path%\my.ini

echo default-storage-engine=INNODB>>%mysql_path%\my.ini

echo.

echo ****正在安装MYSQL服务****

echo.

echo 停止原MYSQL服务

echo.

set service_name=MySQL56

net stop %service_name%

echo.

echo 删除原DATA

echo.

rd /s /q %mysql_path%\data

echo.

echo 删除原MYSQL服务

echo.

%mysql_path%\bin\mysqld.exe --remove %service_name%

echo.

echo 初始化DATA

echo.

md %mysql_path%\data

echo.

echo 安装MYSQL SERVICE

echo.

%mysql_path%\bin\mysqld.exe --initialize --user=mysql --console

%mysql_path%\bin\mysqld.exe --install %service_name%

echo.

echo 启动MYSQL SERVICE,SERVICE NAME : MySQL56

echo.

net start %service_name%

echo.

echo ****************************************

echo.

echo A temporary password is generated for root@localhost:临时密码

echo.

echo 修改密码↓↓↓↓↓↓

echo.

echo mysql -u root -p

echo.

echo 输入临时密码

echo.

echo set password = password('123456');

echo.

echo 成功后使用Navicat导入脚本

echo.

echo ****************************************

:END 

pause

文章评论